cmake: move ps2 cmake toolchain to subdirectory of ps2

cmake/nx/FindNXGL.cmake

@@ -0,0 +1,38 @@
+find_library(NXGL_EGL_LIBRARY EGL)
+find_library(NXGL_GLAPI_LIBRARY glapi)
+find_library(NXGL_DRM_NOUVEAU_LIBRARY drm_nouveau)
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(NXGL
+    REQUIRED_VARS NXGL_EGL_LIBRARY NXGL_GLAPI_LIBRARY NXGL_DRM_NOUVEAU_LIBRARY
+)
+
+if(NXGL_FOUND)
+    if(NOT TARGET NXGL::EGL)
+        add_library(NXGL::EGL UNKNOWN IMPORTED)
+        set_target_properties(NXGL::EGL PROPERTIES
+            IMPORTED_LOCATION "${NXGL_EGL_LIBRARY}"
+        )
+    endif()
+
+    if(NOT TARGET NXGL::glapi)
+        add_library(NXGL::glapi UNKNOWN IMPORTED)
+        set_target_properties(NXGL::glapi PROPERTIES
+            IMPORTED_LOCATION "${NXGL_GLAPI_LIBRARY}"
+        )
+    endif()
+
+    if(NOT TARGET NXGL::drm_nouveau)
+        add_library(NXGL::drm_nouveau UNKNOWN IMPORTED)
+        set_target_properties(NXGL::drm_nouveau PROPERTIES
+            IMPORTED_LOCATION "${NXGL_DRM_NOUVEAU_LIBRARY}"
+        )
+    endif()
+
+    if(NOT TARGET NXGL::OpenGL)
+        add_library(NXGL::OpenGL INTERFACE IMPORTED)
+        set_target_properties(NXGL::OpenGL PROPERTIES
+            INTERFACE_LINK_LIBRARIES "NXGL::EGL;NXGL::glapi;NXGL::drm_nouveau"
+        )
+    endif()
+endif()

cmake/nx/NXFunctions.cmake

@@ -0,0 +1,32 @@
+if(NOT COMMAND nx_generate_nacp)
+    message(FATAL_ERROR "The `nx_generate_nacp` cmake command is not available. Please use an appropriate Nintendo Switch toolchain.")
+endif()
+
+if(NOT COMMAND nx_create_nro)
+    message(FATAL_ERROR "The `nx_create_nro` cmake command is not available. Please use an appropriate Nintendo Switch toolchain.")
+endif()
+
+set(CMAKE_EXECUTABLE_SUFFIX ".elf")
+
+function(librw_platform_target TARGET)
+    cmake_parse_arguments(LPT "INSTALL" "" "" ${ARGN})
+
+    get_target_property(TARGET_TYPE "${TARGET}" TYPE)
+    if(TARGET_TYPE STREQUAL "EXECUTABLE")
+        nx_generate_nacp(${TARGET}.nacp
+            NAME "${TARGET}"
+            AUTHOR "${librw_AUTHOR}"
+            VERSION "${librw_VERSION}"
+        )
+
+        nx_create_nro(${TARGET}
+            NACP ${TARGET}.nacp
+        )
+
+        if(LIBRW_INSTALL AND LPT_INSTALL)
+            install(FILES "${CMAKE_CURRENT_BINARY_DIR}/${TARGET}.nro"
+                DESTINATION "${CMAKE_INSTALL_BINDIR}"
+            )
+        endif()
+    endif()
+endfunction()